PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Fabrice Mouhartem <aur-packages@epheme.re>
#
# Inspired by fanficfare-git's PKGBUILD
# (https://aur.archlinux.org/packages/fanficfare-git)
_pkgname=kalamine
pkgname=kalamine-git
pkgver=r76.b566115
pkgrel=1
pkgdesc="A text-based, cross-platform Keyboard Layout Maker."
arch=('any')
url="https://github.com/fabi1cazenave/${_pkgname}"
license=('MIT')
groups=()
_deps=(
        'click'
        'pyyaml'
        'setuptools'
        'tomli'
        'lxml'
)
depends=("${_deps[@]/#/python-}")
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install=
source=("git+${url}.git")
md5sums=('SKIP')

pkgver() {
	cd "$srcdir/${_pkgname}"

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${_pkgname}"

	python -m build --wheel --no-isolation
}

package() {
	cd "$srcdir/${_pkgname}"

	python -m installer --destdir="${pkgdir}" dist/*.whl
}