blob: 02452e4245a0a6d2fc9e63590c766e7fe0c21012 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="kaskade"
pkgver=4.0.5
pkgrel=1
pkgdesc="A text user interface for Kafka. Interact and consume topics from your terminal in style!"
arch=('any')
url="https://github.com/sauljabin/${pkgname}"
license=('MIT')
depends=('python>=3.10' 'python-click' 'python-cloup>=3' 'python-confluent-kafka>=2.10'
'python-fastavro' 'python-protobuf' 'python-rich' 'python-textual>=3.3')
makedepends=('python-build' 'python-installer' 'python-poetry-core>=2')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('5a9a33974531bf2cedb027b7e3500bbfd3779539dff0b617ea55dd85efb1e2ac')
build() {
cd "${srcdir}/${_pkgsrc}"
python -m build --wheel --no-isolation
}
package() {
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
cd "${srcdir}/${_pkgsrc}"
python -m installer --destdir="${pkgdir}" dist/*.whl
rm -f "${pkgdir}${site_packages}/LICENSE"
install -vDm644 "CHANGELOG.md" "${pkgdir}/usr/share/doc/${pkgname}/CHANGELOG.md"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vd "${pkgdir}/usr/share/licenses/${pkgname}"
ln -vsf "${site_packages}/${_pkgsrc}.dist-info/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|