PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: Integral <integral@member.fsf.org>

pkgname=kazumi
_srcname=Kazumi
pkgver=1.9.4
pkgrel=1
pkgdesc="基于自定义规则的番剧采集APP，支持流媒体在线观看，支持弹幕"
url="https://${pkgname}.app"
license=('GPL-3.0-or-later')
arch=('x86_64' 'aarch64')
depends=(
	'gtk3'
	'webkit2gtk-4.1'
	'libayatana-appindicator'
	'xdg-user-dirs'
	'alsa-lib'
	'libvdpau'
	'libpulse'
	'libxss'
	'libarchive'
	'libcdio'
	'libcdio-paranoia'
	'libdvdnav'
)
makedepends=('clang' 'cmake' 'ninja' 'fvm' 'patchelf')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Predidit/${_srcname}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('d47dc241888d6ef38f39ef56171d312698906b2e2283d9be5f8441febb7336a9')

prepare() {
	cd "${_srcname}-${pkgver}/"
	fvm install stable
	fvm use stable -f
	fvm flutter --disable-analytics
	fvm flutter --no-version-check pub get
}

build() (
	cd "${_srcname}-${pkgver}/"
	fvm flutter build linux --no-pub --release
)

package() {
	cd "${_srcname}-${pkgver}/"

	case "${CARCH}" in
	"x86_64") local _dartarch="x64" ;;
	"aarch64") local _dartarch="arm64" ;;
	esac

	pushd "build/linux/${_dartarch}/release/"
	install -Dm755 "bundle/${pkgname}" -t "${pkgdir}/usr/lib/${pkgname}/"
	cmake -DCMAKE_INSTALL_PREFIX="${pkgdir}/usr/lib/${pkgname}" .
	cmake -P cmake_install.cmake
	popd

	patchelf --set-rpath '$ORIGIN' ${pkgdir}/usr/lib/${pkgname}/lib/*.so

	install -dm755 "${pkgdir}/usr/bin"
	ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"

	local _app_id="io.github.Predidit.Kazumi"
	install -Dm644 "assets/images/logo/logo_linux.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${_app_id}.png"
	install -Dm644 "assets/linux/${_app_id}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}