blob: d61f65cc6d7c10a73d40f66659a79f713cadf86e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Thomas Jost <schnouki@schnouki.net>
pkgname=kcc
pkgver=5.5.2
pkgrel=6
pkgdesc="Kindle Comic Converter converts comic files or folders to ePub or Panel View MOBI"
arch=(any)
url="https://github.com/ciromattia/kcc"
license=('ISC')
depends=('python>=3.10' 'python-pillow>=9.0.0' 'python-psutil>=5.0.0' 'python-pyqt5>=5.6.0' 'python-raven>=6.0.0' 'python-slugify>=6.0.0')
optdepends=(
'kindlegen>=2.9: for .mobi generation'
'p7zip: for zip/CBZ, rar/CBZ, 7z/CB7 support'
)
makedepends=('python-setuptools')
source=(kindlecomicconverter.desktop
kcc-py310.patch
kcc-slugify6.patch
https://github.com/ciromattia/$pkgname/archive/$pkgver.tar.gz)
md5sums=('f25b30fbc1bc1db491173215fe411789'
'4f12019d3efda060bf45bd516831a346'
'9701c427a46aa9d9a2e34062ee0891b1'
'483f06333bbae8e0f4c28252487b9d97')
sha256sums=('3502c38d756f5a812ac06f63fe25e062d8720f620ffd7d25641e6accef9fdd9f'
'72b22f6fea6a7727ef8671e0386291c7d6946f4e8046dc037d46bfd8c3621138'
'43236d6351d95db1405e0f9f2b32e531248886afc3b4c110511d32b7ec1241dd'
'7b45fcdf0149bea36e8c738e76031790c8c235c777047001279698a526be892b')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
patch -p0 < "$srcdir"/kcc-py310.patch
patch -p0 < "$srcdir"/kcc-slugify6.patch
}
build() {
cd "$srcdir/$pkgname-$pkgver"
python setup.py build
}
package() {
cd "$srcdir/$pkgname-$pkgver/"
# Install by hand. I don't want to use Docker to use fpm to build a Debian package…
python setup.py install --root="$pkgdir/"
# For some reason there's an error with PyQt5 not being detected by setuptools. So… hack.
find "$pkgdir" -name requires.txt -delete
# Install other required files
install -Dm644 "$srcdir/kindlecomicconverter.desktop" "$pkgdir/usr/share/applications/kindlecomicconverter.desktop"
install -Dm644 icons/comic2ebook.png "$pkgdir/usr/share/pixmaps/kcc.png"
install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/${pkgname}/LICENSE.txt"
install -Dm644 README.md "$pkgdir/usr/share/docs/${pkgname}/README.md"
}
|