PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
# Contributor: Solomon Choina <shlomochoina@gmail.com>

pkgname=kcm-grub2-git
_product="${pkgname%-git}"
pkgver=0.6.4.r86.g1912ede
pkgrel=1
pkgdesc='KDE Control Module for configuring the GRUB bootloader'
arch=('x86_64')
url='https://invent.kde.org/system/kcm-grub2'
license=('GPL3')
depends=(
    'grub'
    'hwinfo'
    'kcmutils'
    'libmagick6'
    'packagekit-qt5'
)
makedepends=(
    'cmake'
    'extra-cmake-modules'
    'git'
    'kdoctools'
    'ninja'
)
optdepends=('os-prober: To detect other OSes when generating grub.cfg in BIOS systems')
source=("${_product}"::"git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_product}"
  # cutting off 'v' prefix that presents in the git tag
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  rm -rfv build
  export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
  cmake \
    -B build -S "${_product}" \
    -G Ninja \
    -D BUILD_TESTING=OFF \
    -Wno-dev

  cmake --build build
}

package() {
	DESTDIR="${pkgdir}" cmake --install build
}