PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

pkgname=kcm-pointing-devices-git
pkgver=r45.5989dd6
pkgrel=1
pkgdesc="Mouse/touchpad configuration module for KDE"
arch=('i686' 'x86_64')
url='https://github.com/amezin/pointing-devices-kcm'
license=('GPL')
depends=('kded' 'kcmutils' 'kdeclarative' 'libxcb-git' 'xcb-proto-git')
makedepends=('extra-cmake-modules' 'qt5-tools')
source=("git://github.com/amezin/pointing-devices-kcm.git")
groups=('plasma')
md5sums=('SKIP')

pkgver() {
  cd pointing-devices-kcm
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../pointing-devices-kcm \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DSYSCONF_INSTALL_DIR=/etc \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}