PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer : Daniel Bermond < gmail-com: danielbermond >
# Contributor: Antonio Rojas <arojas@archlinux.org>

pkgname=kde-gtk-config-git
_srcname=kde-gtk-config
pkgver=5.13.90a.r18.g6628e53
pkgrel=1
pkgdesc='GTK2 and GTK3 Configurator for KDE'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/workspace/kde-gtk-config'
license=('LGPL')
depends=('systemsettings' 'gtk2' 'gtk3')
makedepends=('git' 'extra-cmake-modules')
conflicts=('kde-gtk-config')
provides=('kde-gtk-config')
source=('git+https://anongit.kde.org/kde-gtk-config.git')
groups=('plasma')
md5sums=('SKIP')

pkgver() {
    cd "$_srcname"
    
    # git, tags available
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

prepare() {
    cd "$_srcname"
    
    mkdir -p build
}

build() {
    cd "${_srcname}/build"
    
    cmake \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DLIB_INSTALL_DIR='lib' \
        -DLIBEXEC_INSTALL_DIR='lib' \
        -DKDE_INSTALL_USE_QT_SYS_PATHS='ON' \
        -DBUILD_TESTING='ON' \
        -Wno-dev \
        ..
        
    make
}

check() {
    cd "${_srcname}/build"
    
    make test
}

package() {
    cd "${_srcname}/build"
    
    make DESTDIR="$pkgdir" install
}