summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 762ccd1c59076a73a49e15735058a8f8e13648d5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Martin

_module=kuickshow
pkgname=kde1-${_module}-git
pkgver=0.2.1.r6.ca926a2
pkgrel=1
pkgdesc="Historical copy of $_module for KDE 1, adapted to compile on modern systems"
arch=(i686 x86_64)
url="https://github.com/sandsmark/kde1-${_module}/"
license=("GPL2")
groups=(kde1)
depends=(kde1-kdelibs)
makedepends=(cmake git)
provides=(kde1-kde${_module})
conflicts=(kde1-kde${_module})

# Mirror
source=("git+https://github.com/sandsmark/kde1-${_module}.git")

md5sums=('SKIP')

pkgver() {
  cd kde1-${_module}
  printf "0.2.1.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  if [[ -d build ]]; then
    rm -rf build && mkdir build
  else
    mkdir build
  fi
}

build() {
  cd build
  cmake "$srcdir"/kde1-${_module} -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir/" install
  cd "$srcdir"/kde1-${_module}
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}