PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Andrew Shark <ashark linuxcomp ru>
# Contributor: Ben Isenhart <bisenhar(at)uvm(dot)edu>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Wang Jiajun <amesists@gmail.com>

pkgname=kdesrc-build-git
pkgver=22.07.r580.g6513976
pkgrel=1
pkgdesc="A script to build KDE software from KDE's source repositories"
url="https://apps.kde.org/kdesrc_build"
arch=("any")
license=("GPL")
depends=("perl-json" "perl-json-xs" "perl-yaml-libyaml" "perl-io-socket-ssl" "perl-libwww" "perl-xml-parser")
makedepends=("cmake" "git")
source=("git+https://invent.kde.org/sdk/kdesrc-build.git")
sha256sums=("SKIP")

pkgver() {
  cd kdesrc-build
  git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cmake \
    -S kdesrc-build \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  mkdir "${pkgdir}/usr/bin"
  ln -sfv "/usr/share/kdesrc-build/kdesrc-build" "${pkgdir}/usr/bin/kdesrc-build"
  ln -sfv "/usr/share/kdesrc-build/kdesrc-run" "${pkgdir}/usr/bin/kdesrc-run"
}