summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 70e75948ecdcd4528476bc5b52bde64c04d0046b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Antonio Rojas <arojas@archlinux,org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kdialog-git
pkgver=1.0.1036.60c9569
pkgrel=1
pkgdesc="KDialog can be used to show nice dialog boxes from shell scripts. (GIT version)"
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/applications/kdialog'
license=('LGPL')
depends=('kdelibs4support')
makedepends=('extra-cmake-modules'
             'git'
             'python'
             )
conflicts=('kdebase-kdialog'
           'kdialog'
           )
provides=('kdialog')
source=('git://anongit.kde.org/kdialog')
sha256sums=('SKIP')

pkgver() {
  cd kdialog
  _ver="$(cat src/kdialog.cpp | grep -m1 'i18n( ' | sed 's|i18n|ixxn|g' | cut -d '"' -f2)"
  echo "${_ver}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../kdialog \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}
package() {
  make -C build DESTDIR="${pkgdir}" install
}