PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

pkgname=kdocker
pkgver=5.0
pkgrel=1
pkgdesc="An application to help you dock any application into the system tray"
arch=('i686' 'x86_64')
url="https://github.com/user-none/KDocker"
license=('GPL2')
depends=('qt5-base' 'qt5-x11extras' 'libxpm' 'libxmu')
source=(https://github.com/user-none/KDocker/archive/${pkgver}.tar.gz)
sha256sums=('711c3a07d36d278eca47fa56db34fcb0f20f30210d9a1e86a9d0243b834e357a')

build() {
    cd "$srcdir/KDocker-$pkgver"

    sed -i '/<QCoreApplication>/ a\#include <QDataStream>' 3rdparty/qtsingleapplication/src/qtlocalpeer.cpp

    qmake-qt5
    make
}

package() {
    cd "$srcdir/KDocker-$pkgver"

    install -Dm755 "kdocker"                             "$pkgdir/usr/bin/kdocker"
    install -Dm644 "helpers/appdata/kdocker.appdata.xml" "$pkgdir/usr/share/appdata/kdocker.appdata.xml"
    strip "$pkgdir/usr/bin/kdocker"
    install -Dm644 "resources/images/kdocker.png"        "$pkgdir/usr/share/pixmaps/kdocker.png"
    install -Dm644 "helpers/kdocker.desktop"             "$pkgdir/usr/share/applications/kdocker.desktop"
    install -Dm644 "helpers/kdocker"                     "$pkgdir/etc/bash_completion.d/kdocker"
    install -Dm644 "helpers/kdocker.1"                   "$pkgdir/usr/share/man/man1/kdocker.1"
}