blob: 216d5a017053b3b3373b83f4e12a6a7516ff6e0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: envolution
# Contributor: mdaniels5757 <arch at mdaniels dot me>
# Contributor: ejiek <ejiek@mail.ru>
# Contributor: jskier <jay @jskier.com>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=keeper-commander
pkgver=17.0.6
pkgrel=1
epoch=1
pkgdesc="CLI, SDK and interactive shell for Keeper® Password Manager."
arch=('any')
url="https://github.com/Keeper-Security/Commander"
license=('MIT')
depends=('python'
'python-asciitree'
'python-bcrypt'
'python-colorama'
'python-prompt_toolkit'
'python-pycryptodomex'
'python-pyperclip'
'python-pysocks'
'python-tabulate'
'python-websockets'
'python-fido2'
'python-requests'
'keeper-secrets-manager-core>=16.6.0'
'python-aiortc'
'python-protobuf'
'python-cryptography'
'python-pykeepass'
'python-pydantic'
)
makedepends=(
'python-installer'
'python-build'
'python-setuptools'
'python-setuptools-scm'
)
checkdepends=('python-ifaddr' 'python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('3d15b9e52d23bba9fe6f981bf343387a1219977e3176b6d2b2e11570e776559b0063e411c4b77949f3a0e6a6f49d2607f203d924f4a2265db6ee87abcf8e3e62')
build() {
cd "Commander-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "Commander-$pkgver"
python -m pytest -s -v -k \
"not test_forward_data_to_tunnel_generic_exception and \
not test_add_enterprise_user and \
not test_commands and \
not test_report_commands and \
not test_quoting and \
not test_vault_reports"
}
package() {
cd "Commander-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|