blob: 74e5998878d876f4d02420ecc43dd379799b52ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: surefire <surefire at cryptomile dot net>
# Contributor wenLiangcan <boxeed at gmail dot com>
pkgname=keeweb-git
pkgver=1.6.3+192+g9b9cda3
pkgrel=1
pkgdesc="Desktop password manager compatible with KeePass databases. (develop branch)"
arch=('any')
url="https://github.com/keeweb/keeweb"
license=('MIT')
depends=('electron')
makedepends=(
'asar'
'npm'
'libsass'
)
optdepends=('xdotool: for auto-type')
conflicts=('keeweb' 'keeweb-desktop')
provides=('keeweb' 'keeweb-desktop')
source=(
"${pkgname}::git+https://github.com/keeweb/keeweb.git#branch=develop"
'hide-menubar.patch'
'package.json.patch.js'
'keeweb.sh'
)
sha1sums=('SKIP'
'a55c2ed276c6073b7954452cdc88209633d51ace'
'3cad1556a5a855a3ab5152f1b2cb175287bd8368'
'a2ab033d06abfe7616d2615d8edf7931f29efc96')
pkgver() {
cd "${pkgname}"
git describe --long --tags | sed 's/^v//; s/_/./g; s/-/+/g'
}
prepare() {
cd "${pkgname}"
patch -Np1 -i ../hide-menubar.patch
# remove extra dependencies
node ../package.json.patch.js
sed -i \
-e "/electronVersion/ d" \
-e "/loader: 'babel-loader'/,+2 d" \
-e "/loader: 'uglify-loader'/ d" \
-e "/'eslint',/ d" \
-e "/'uglify',/ d" \
Gruntfile.js
sed -i \
-e '/Exec=/ c \Exec=keeweb %u' \
package/deb/usr/share/applications/keeweb.desktop
}
build() {
cd "${pkgname}"
export SKIP_SASS_BINARY_DOWNLOAD_FOR_CI=1
export LIBSASS_EXT=auto
npm install --no-package-lock
node_modules/.bin/grunt --skip-sign build-web-app build-desktop-app-content
asar p tmp/desktop/app ../keeweb.asar
}
package() {
cd "${pkgname}"
install -Dm0755 ../keeweb.sh "${pkgdir}/usr/bin/keeweb"
install -Dm0644 -t "${pkgdir}/usr/lib/keeweb" ../keeweb.asar
install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE DEPS-LICENSE
install -Dm0644 -t "${pkgdir}/usr/share/mime/packages" package/deb/usr/share/mime/packages/keeweb.xml
install -Dm0644 -t "${pkgdir}/usr/share/applications" package/deb/usr/share/applications/keeweb.desktop
install -Dm0644 graphics/128x128.png "${pkgdir}/usr/share/pixmaps/keeweb.png"
}
|