PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Danko Aleksejevs <danko@very.lv>
# Contributor: Matthias De Bie <mattydebie@gmail.com>
# Contributor: Yi donghoon <icq4ever@gmail.com>
pkgname='kemai-git'
pkgdesc='A QT6 client for Kimai time tracker'
pkgver=0.12.0.r448.79f33f5
pkgrel=1
url='https://github.com/AlexandrePTJ/kemai'
arch=('i686' 'x86_64')
license=('MIT')
source=('git+https://github.com/AlexandrePTJ/kemai.git#branch=develop')
sha256sums=('SKIP')
makedepends=('git' 'cmake' 'range-v3' 'magic_enum' 'qt6-tools')
depends=('qt6-base' 'spdlog' 'libxss' 'hicolor-icon-theme')
provides=('kemai')
conflicts=('kemai')

pkgver() {
  cd kemai
  echo $(grep -oP '(?<=KemaiProject VERSION )\S+' CMakeLists.txt) .r $(git rev-list --count HEAD) . $(git rev-parse --short HEAD) | tr -d '[:space:]'
}

build() {
  cmake kemai \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DKEMAI_BUILD_LOCAL_DEPENDENCIES=OFF \
    -DCMAKE_CXX_STANDARD_INCLUDE_DIRECTORIES=/usr/include/magic_enum \
    -Wno-dev
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 kemai/LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}