PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: kbtz <contact@kbtz.dev>
# Contributor: eNV25 <env252525@gmail.com>

pkgref=keyd
pkgname=keyd-openrc
pkgver=2.4.3.r10.eeea96a
pkgrel=1
arch=('x86_64' 'aarch64')
pkgdesc='A key remapping daemon for linux'
url='https://github.com/rvaiya/keyd'
license=('MIT')
makedepends=(git)
depends=(openrc)
provides=($pkgref)
conflicts=($pkgref)
optdepends=('python3: for keyd-application-mapper')
sha256sums=('SKIP' 'SKIP' 'SKIP')
source=(
	'git+https://github.com/rvaiya/keyd.git'
	tweaks.patch
	keyd.init
)

pkgver() {
	cd $srcdir/$pkgref
	git describe --long --tags | sed -E '
		s/([^-]*-)g/r\1/
		s/-/./g
		s/^v//
	'
}

prepare(){ 
	patch -p0 -d $srcdir/$pkgref -i $srcdir/tweaks.patch
}

build() {
	cd $srcdir/$pkgref
	make
}

package() {
	cd $srcdir
	install -Dm755 $pkgref.init $pkgdir/etc/init.d/$pkgref
	install -dm755 $pkgdir/usr/share/libinput
	
	cd $pkgref
	make DESTDIR=$pkgdir PREFIX=/usr install
	install -Dm644 LICENSE -t ${pkgdir}/usr/share/licenses/$pkgref
}