blob: 2065fcc227383c458e26c02cfd0ccefb7cda2847 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: houmain <houmain at posteo dot net>
pkgname=keymapper
pkgver=4.12.1
pkgrel=1
pkgdesc="A cross-platform context-aware keyremapper"
arch=(i686 x86_64 armv7h aarch64)
url=https://github.com/houmain/keymapper
license=(GPL-3.0-or-later)
depends=(dbus gcc-libs libappindicator-gtk3 libusb libx11 libxkbcommon
libxkbcommon-x11 wayland)
makedepends=(cmake)
source=(${url}/archive/$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('14331bea9bf3ee35127c76221cf66a233f4a1879dd057e4b32c5497646ad0552')
prepare() {
cd $pkgname-$pkgver
# use full path for execstart
sed -i 's|^ExecStart=keymapperd|ExecStart=/usr/bin/keymapperd|' \
extra/lib/systemd/system/keymapperd.service
}
build() {
cd $pkgname-$pkgver
cmake . -DVERSION="$pkgver" -DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
# vim: set ts=2 sw=2 et:
|