PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Jai-JAP <jai dot jap dot 318 at gmail dot com>
pkgname=keymapper-bin
pkgver=4.11.4
pkgrel=1
pkgdesc="A cross-platform context-aware keyremapper"
arch=(x86_64 aarch64)
url=https://github.com/houmain/keymapper
conflicts=(keymapper)
provides=(keymapper)
license=("GPL-3.0-or-later")
depends=(dbus gcc-libs libayatana-appindicator libappindicator-gtk3 libusb libx11 libxkbcommon wayland)

source=(autostart.desktop)
sha256sums=('b3312492e497b5976501a42445b70309183811da545257742f7b99364cdca402')

source_x86_64=(${pkgname%-bin}-amd64.tgz::${url}/releases/download/${pkgver}/${pkgname%-bin}-${pkgver}-Linux-x86_64.tar.gz)
sha256sums_x86_64=('b4f35f3e3737df307c696ca4b0c92af4c05f607b2f58d689f4db956b8ef8bb7b')

source_aarch64=(${pkgname%-bin}-arm64.tgz::${url}/releases/download/${pkgver}/${pkgname%-bin}-${pkgver}-Linux-arm64.tar.gz)
sha256sums_aarch64=('f662cfa2b0d6b6f96d12cfb768c54bc1ba0d3fc1ea65532cab29f8cc94f818e0')

_arch=${CARCH/aarch64/arm64}

prepare() {
  # Taken from keymapper aur script <https://aur.archlinux.org/packages/keymapper>
  sed -i 's|^ExecStart=keymapperd|ExecStart=/usr/bin/keymapperd|' \
    ${pkgname%-bin}-${pkgver}-Linux-${_arch}/usr/lib/systemd/system/keymapperd.service
}

package() {
  for dir in usr etc; do
    cp -r ${pkgname%-bin}-${pkgver}-Linux-${_arch}/${dir} ${pkgdir}/
  done
}