PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: svan71 <Keystone.osk@gmail.com>

pkgname=keystone-osk
pkgver=0.9.1
pkgrel=1
pkgdesc="Practical on-screen keyboard for Linux desktops"
arch=('any')
url="https://github.com/svan71/keystone-osk"
license=('GPL-3.0-or-later')
# ydotool is invoked as a subprocess by keystone_osk/backend.py, so namcap
# cannot see it and reports it as possibly unneeded. It is required.
depends=('python' 'pyside6' 'ydotool' 'hicolor-icon-theme')
optdepends=('gnome-shell-extension-appindicator: top-bar tray icon on GNOME')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('a98e9a0b3181d764597d5eadcc8b321d8b556bc017ec5d0f04bbcb47d8413c1c')

build() {
  cd "$srcdir/$pkgname-$pkgver/source"
  python -m build --wheel --no-isolation
}

check() {
  cd "$srcdir/$pkgname-$pkgver/source"
  QT_QPA_PLATFORM=offscreen python -m pytest -q
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  python -m installer --destdir="$pkgdir" source/dist/*.whl

  install -Dm644 source/LICENSE \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 live-install/applications/keystone-osk.desktop \
    "$pkgdir/usr/share/applications/keystone-osk.desktop"
  install -Dm644 live-install/icons/hicolor/256x256/apps/keystone.png \
    "$pkgdir/usr/share/icons/hicolor/256x256/apps/keystone.png"
  install -Dm644 live-install/icons/hicolor/256x256/apps/keystone-transparent.png \
    "$pkgdir/usr/share/icons/hicolor/256x256/apps/keystone-transparent.png"
  install -Dm644 packaging/io.github.svan71.keystone-osk.metainfo.xml \
    "$pkgdir/usr/share/metainfo/io.github.svan71.keystone-osk.metainfo.xml"
}