summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a28405620b97c1eacb2e122069d2a8394a297bf9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=khtml-git
pkgver=r233.093c96c
pkgrel=2
pkgdesc='KHtml'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/frameworks/khtml'
license=('LGPL')
depends=('kparts-git' 'kjs-git' 'giflib')
makedepends=('extra-cmake-modules-git' 'git')
optdepends=('java-environment')
groups=('kf5-aids')
conflicts=('khtml')
provides=('khtml')
source=('git://anongit.kde.org/khtml.git')
md5sums=('SKIP')

pkgver() {
  cd khtml
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../khtml \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}