blob: ecbdd02e01ff4377dddaf2f9c6480cbf4cb4e3de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Eric Liu <eric@hnws.me>
# Official repo maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Official repo maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Official repo Contributor: Spider.007 <archlinux AT spider007 DOT net>
pkgname=kibana-xpack
relpkgname=kibana
pkgver=6.6.2
pkgrel=1
pkgdesc='Browser based analytics and search dashboard for Elasticsearch'
url='https://www.elastic.co/products/kibana'
arch=('any')
license=('Apache')
depends=('nodejs')
optdepends=('elasticsearch')
provides=('kibana')
conflicts=('kibana')
backup=('etc/kibana/kibana.yml')
options=('!strip' 'emptydirs')
source=(https://artifacts.elastic.co/downloads/$relpkgname/$relpkgname-${pkgver}-linux-x86_64.tar.gz
kibana.service
tmpfile.conf
user.conf)
sha512sums=('9cc392c5f3de3b340a15903b2f0472405e6a6ea209a9b101a9d573aa304774c516f617b7a2c64f2a9523d74f5f3c847e16f6d7c81cc65d8b17bbed268bbb7065'
'3216c2864cf184cea0883677a05bf83cf396fda52dbd3d9a187de22f0c45d13db58f8fb4dc926694ba7d7a24000cf6d5f6218805f74fb5d729fc85c643ca8f2f'
'afed49c164561f3c658a6d2423519adcf4d5293c416cd93fa5c9d12421416c1e9cb4287e832009049cfd014b365dc1cd93d9cf879117c701cce4caad3b772a8e'
'9085884430c656cc68b855c3d6740e5fd0854a8785930341b29e15e201deacc1870d8223255d9ebe096cb111319bea9bf4faa03d0760d5819976ebf912221c7d')
prepare() {
cd $relpkgname-${pkgver}-linux-x86_64
# remove nodejs strict version requirements
sed "s@^require('./node_version_validator');@// \0@" -i src/setup_node_env/index.js
# set default quiet mode for systemd, cli option forces specified values
sed -r 's|#(logging.quiet:) false|\1 true|' -i config/kibana.yml
}
package() {
cd $relpkgname-${pkgver}-linux-x86_64
install -dm 755 "${pkgdir}/usr/share/kibana"
cp -a * "${pkgdir}/usr/share/kibana"
install -dm 750 "${pkgdir}/etc/kibana"
install -Dm 640 config/kibana.yml -t "${pkgdir}/etc/kibana"
install -Dm 644 "${srcdir}/kibana.service" -t "${pkgdir}/usr/lib/systemd/system"
install -Dm 644 "${srcdir}/user.conf" "${pkgdir}/usr/lib/sysusers.d/kibana.conf"
install -Dm 644 "${srcdir}/tmpfile.conf" "${pkgdir}/usr/lib/tmpfiles.d/kibana.conf"
rm -r "${pkgdir}/usr/share/kibana/node"
find "${pkgdir}/usr/share/kibana/node_modules" -type d -empty -delete
}
# vim: ts=2 sw=2 et:
|