blob: 123ba47cb233cd6ef3329d7a4f441cc959f39811 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Ilaï Deutel <PlMWPh1WSmypRv0JQljz> (echo ... | tr 'A-Za-z' 'l-za-kL-ZA-K' | base64 -d)
pkgname=kibi
pkgver=0.3.3
pkgrel=1
pkgdesc="A tiny text editor, written in Rust"
url="https://github.com/ilai-deutel/kibi"
makedepends=('cargo')
depends=('gcc-libs' 'glibc' 'hicolor-icon-theme')
arch=('x86_64' 'i686' 'armv6h' 'armv7h' 'aarch64')
license=('MIT OR Apache-2.0')
backup=('etc/kibi/config.ini')
source=("https://github.com/ilai-deutel/kibi/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
b2sums=('3cef474de5ed911506caa7c0764eba5d9f90e32ee529ca6b85eefb57a95a3906dc574f7c6abc4c4fe349c29f368ca47807e00322391ea75be3bb74449c1732c8')
prepare() {
export RUSTUP_TOOLCHAIN=stable
cd "$pkgname-$pkgver"
cargo fetch --locked --target host-tuple
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$pkgname-$pkgver"
cargo build --frozen --release --all-features
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd "$pkgname-$pkgver"
cargo test --frozen --all-features
}
package() {
cd "$pkgname-$pkgver"
# Install binary
install -Dm755 "target/release/kibi" -t "$pkgdir/usr/bin"
# Install configuration files
install -Dm644 "config_example.ini" "$pkgdir/etc/kibi/config.ini"
install -Dm644 syntax.d/* -t "$pkgdir/usr/share/kibi/syntax.d"
# Install desktop file and logo
install -Dm644 kibi.desktop -t "$pkgdir/usr/share/applications"
install -Dm644 assets/kibi.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/kibi.svg"
# Install license
install -Dm644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
}
|