PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: rhssk <rhssk@posteo.eu>
pkgname=kicost-git
_remotename=KiCost
pkgver=1.1.6.r1.227f246
pkgrel=1
pkgdesc="Build cost spreadsheet for a KiCad project"
url="https://github.com/hildogjr/KiCost"
depends=(
    python
    python-beautifulsoup4
    python-lxml
    python-xlsxwriter
    python-tqdm
    python-requests
    python-validators
    python-wxpython
    python-colorama
)
makedepends=(
    git
    python-setuptools
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
license=('MIT')
arch=('any')
source=('git+https://github.com/hildogjr/KiCost.git')
sha256sums=('SKIP')

pkgver() {
    cd "$_remotename"

    printf "%s" "$(git describe --long | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}

check() {
    cd "$_remotename"

    python -m unittest tests.test_kicost
}

package() {
    cd "$_remotename"

    python setup.py install --root="$pkgdir" --optimize=1
}