PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Scott Alfter <scott@alfter.us>
# Contributor: Julian Daube <joposter at gmail dot com>
pkgname=kikit-git
pkgdesc="Automation for KiCAD boards"
pkgver=r751.4f1a424
pkgrel=3

url="https://github.com/yaqwsx/KiKit.git"

arch=("any")
provides=("kikit")
license=("MIT")
conflicts=("python-kikit")

source=("$pkgname::git+https://github.com/yaqwsx/KiKit.git")
md5sums=("SKIP")
makedepends=(
	"python-setuptools" 
	"python-versioneer"
	"python-build"
	"python-installer"
)
depends=(
	"kicad>=5.1.0"
	"python-shapely"
	"python-solidpython"
	"python-numpy"
	"python-click"
	"python-markdown2"
	"python-commentjson"
	"python-matplotlib"
	"python-pybars3"
	"python-pcbnewtransition"
)
optdepends=("python-wxpython: for plugin hideReferences")


pkgver() {
	cd "$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build()
{
	cd "$pkgname"
	python -m build --wheel --no-isolation
}

package() {
	cd "$pkgname"
	python -m installer --destdir="$pkgdir/" dist/*.whl

	# install license
	install -Dm 644 LICENCE "$pkgdir"/usr/share/licenses/kikit/LICENSE
}