blob: ed7511d8cc47051e774d31f338298f0970d4ba50 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer:
_pkgname="kimageannotator"
pkgname="$_pkgname-git"
pkgver=0.7.1.r13.gb8b8734
pkgrel=1
pkgdesc="Tool for annotating images"
url="https://github.com/ksnip/kImageAnnotator"
license=('LGPL-3.0-only')
arch=('x86_64')
depends=(
'kcolorpicker'
'qt6-svg'
)
makedepends=(
'cmake'
'git'
'ninja'
'qt6-tools'
)
provides=("$_pkgname")
conflicts=(
"$_pkgname"
"$_pkgname-qt6"
)
_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgsrc"
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
local _cmake_options=(
-B build
-S "$_pkgsrc"
-G Ninja
-DCMAKE_BUILD_TYPE=None
-DCMAKE_INSTALL_PREFIX='/usr'
-DBUILD_SHARED_LIBS=ON
-DBUILD_WITH_QT6=ON
-Wno-dev
)
cmake "${_cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|