PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

# Maintainer: Andreas Baumann <mail@andreasbaumann.cc>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kio5-extras
pkgver=24.02.2
pkgrel=10
pkgdesc='Additional components to increase the functionality of KIO'
arch=(x86_64)
url='https://www.kde.org/'
license=(LGPL-2.0-or-later)
depends=(glibc
         karchive5
         kconfig5
         kcoreaddons5
         kdbusaddons5
         ki18n5
         kio5
         libgcc
         libimobiledevice
         libmtp
         libplist
         libssh
         libstdc++
         libtirpc
         libxcursor
         qt5-base
         qt5-svg
         solid5
         syntax-highlighting5)
makedepends=(extra-cmake-modules
             gperf
             libappimage
             openexr
             taglib)
optdepends=('kimageformats5: thumbnails for additional image formats'
            'libappimage: AppImage thumbnails'
            'openexr: EXR format thumbnails'
            'perl: info kioslave'
            'qt5-imageformats: thumbnails for additional image formats'
            'taglib: audio file thumbnails')
source=(https://download.kde.org/stable/release-service/$pkgver/src/kio-extras-kf5-$pkgver.tar.xz{,.sig})
sha256sums=('a9aaf58f3b802c8341bba1ceb95054f915059ea447f59ffc7b933cca71b12ac9'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

prepare() {
# Fix build with libxml2 2.15
  sed -e 's|"extension "|"extension"|' -i kio-extras-kf5-$pkgver/po/it/docs/kioslave5/bzip2/index.docbook
# Drop docs
  sed -e '/DocTools/d' -e '/( doc )/d' -e '/kdoctools_install/d' -i kio-extras-kf5-$pkgver/CMakeLists.txt
# Drop kio-smb
  sed -e '/DNSSD/d' -e '/add_subdirectory(smb)/d' -i kio-extras-kf5-$pkgver/CMakeLists.txt
}

build() {
  cmake -B build -S kio-extras-kf5-$pkgver \
    -DLIBAPPIMAGE_LIBRARIES=libappimage.so \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DBUILD_ACTIVITIES=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}