blob: c792b70dc2ce423929f3768ecefd9ea5caa0c1cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Alexander Paetzelt <techge+arch [ät] posteo [do] net>
pkgname=kismet-git
pkgver=r8139.8baa2896
pkgrel=1
pkgdesc="Current development version based on git repo"
arch=('x86_64')
url="https://www.kismetwireless.net/"
license=('GPL')
depends=('libelf' 'libmicrohttpd' 'libnm' 'libpcap' 'pkg-config' 'protobuf-c' 'lm_sensors')
optdepends=('hackrf: use with HackRF compatible software defined radio (SDR)')
conflicts=('kismet')
backup=('etc/kismet/kismet.conf' 'etc/kismet/kismet_alerts.conf' 'etc/kismet/kismet_httpd.conf' 'etc/kismet/kismet_logging.conf' 'etc/kismet/kismet_memory.conf' 'etc/kismet/kismet_storage.conf')
install=${pkgname}.install
source=("git+https://github.com/kismetwireless/kismet"
"${pkgname}-sysusers.conf")
sha256sums=('SKIP'
'8b5b25bb6d9c611589ce0200da3cfeed2194bfa45aeed88e10c980c668383806')
pkgver() {
cd "$srcdir/kismet"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/kismet"
# include submodule for docs
git submodule update --init docs
}
build() {
cd "$srcdir/kismet"
./configure --prefix=/usr \
--sysconfdir=/etc/kismet \
--disable-python-tools
make
}
package() {
cd "$srcdir/kismet"
make DESTDIR="$pkgdir/" install
# install capture_tools setuid so that kismet can started as user and
# network device can get handled by capture tools
install -o root -g 315 -m 4550 capture_linux_wifi/kismet_cap_linux_wifi "${pkgdir}/usr/bin/"
install -o root -g 315 -m 4550 capture_linux_bluetooth/kismet_cap_linux_bluetooth "${pkgdir}/usr/bin/"
# include docs in /usr/share/doc/
mkdir -p ${pkgdir}/usr/share/doc/$pkgname
cp -r docs/* "$pkgdir/usr/share/doc/$pkgname/"
# create group kismet via sysusers
cd "$srcdir"
install -vDm 644 "${pkgname}-sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}
|