blob: c9f406a01f95b2bb003915c6c8fea21f1b903de1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgname=kjobwidgets-git
pkgver=v4.100.0.rc1.r237.gc8b284d
pkgrel=1
pkgdesc='KJobWidgets'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/frameworks/kjobwidgets'
license=('LGPL')
depends=('kcoreaddons-git' 'kwidgetsaddons-git' 'qt5-x11extras')
makedepends=('extra-cmake-modules-git' 'git' 'qt5-tools')
groups=('kf5')
conflicts=(kjobwidgets)
provides=(kjobwidgets)
source=('git://anongit.kde.org/kjobwidgets.git')
md5sums=('SKIP')
pkgver() {
cd ${pkgname%-git}
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../kjobwidgets \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|