blob: b9cc5225f5b2f22a157437877f87e8a99bbc7254 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: Rocket Aaron <i at rocka dot me>
# Contributor: Art Dev <artdevjs at gmail dot com>
_pkgname=klassy
pkgbase="${_pkgname}"
pkgname=("${_pkgname}"
"${_pkgname}-qt5")
pkgver=6.4.breeze6.4.0
pkgrel=1
pkgdesc='Highly customizable binary Window Decoration, Application Style and Global Theme plugin for recent versions of the KDE Plasma desktop.'
arch=(x86_64)
url="https://github.com/paulmcauley/klassy"
license=('GPL-2.0-only AND GPL-3.0-only AND GPL-2.0-or-later AND LGPL-2.1-or-later AND MIT')
replaces=(classik)
depends=(breeze-icons
hicolor-icon-theme
frameworkintegration
gcc-libs
glibc
kcmutils
kcolorscheme
kconfig
kcoreaddons
kdecoration
kguiaddons
ki18n
kiconthemes
kirigami
kwidgetsaddons
kwindowsystem
qt6-base
qt6-declarative
qt6-svg
xdg-utils)
makedepends=(extra-cmake-modules
kcmutils5
frameworkintegration5
kconfigwidgets5
kiconthemes5
kirigami2
kwindowsystem5)
source=("${_pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('77c757b5edef9808a84fe50f9277369ecafc38fba8d7cda11eb448c0c170a3ff')
#prepare() {
# cd "${_pkgname}-${pkgver}"
# patch -Np1 < "${srcdir}/plasma6.3.patch"
#}
build() {
cmake -B build -S "${_pkgname}-${pkgver}" \
-DBUILD_TESTING=OFF \
-DBUILD_QT5=OFF
cmake --build build
CMAKE_PREFIX_PATH="/usr/lib/cmake/plasma5" cmake \
-B build5 -S "${_pkgname}-${pkgver}" \
-DBUILD_TESTING=OFF \
-DBUILD_QT6=OFF
cmake --build build5
}
package_klassy() {
DESTDIR="${pkgdir}" cmake --install build
install -Dm644 "${_pkgname}-${pkgver}/LICENSES/MIT.txt" "${pkgdir}/usr/share/licenses/${_pkgname}/MIT.txt"
}
package_klassy-qt5() {
depends=("${_pkgname}"
breeze-icons
gcc-libs
glibc
frameworkintegration5
kconfig5
kconfigwidgets5
kguiaddons5
kiconthemes5
kirigami2
kwindowsystem5
qt5-base
qt5-declarative
qt5-svg)
DESTDIR="${pkgdir}" cmake --install build5
rm -r "${pkgdir}/usr/share/"{color-schemes,kstyle}
install -Dm644 "${_pkgname}-${pkgver}/LICENSES/MIT.txt" "${pkgdir}/usr/share/licenses/${_pkgname}-qt5/MIT.txt"
}
|