blob: 693cb75772c6861e48e588fe16aa316ef521ff31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Torleif Skår <torleif.skaar AT gmail DOT com>
pkgname=klayout-pex
pkgver=0.6.8
pkgrel=1
pkgdesc="Parasitic Extraction (PEX) tool for KLayout"
arch=("any")
_git_url="https://github.com/iic-jku/klayout-pex"
url="https://iic-jku.github.io/klayout-pex-website"
license=('GPL-3.0-or-later')
depends=(
'klayout'
'python'
'python-packaging'
'python-matplotlib'
'python-protobuf'
'python-rich'
'python-rich-argparse'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
'python-poetry-core'
'python-grpcio-tools'
)
checkdepends=(
'python-pytest'
'python-allure-commons'
'python-csv-diff'
)
optdepends=(
'python-cairosvg'
"magic: Alternative parasitic extraction backend"
"fastercap: Alternative parasitic extraction backend"
"fastcap2: Alternative parasitic extraction backend"
"meshlab: For previewing 3D geometries (STL) representing input to FasterCap"
)
options=()
source=("${pkgname}::git+${_git_url}#tag=v${pkgver}")
b2sums=('25be75bbaa3faca1c0365f7c77a77c228833fbecd235ad39720a6e786a15d8c8332ab55ae4199e3de7cf3f866bf35b491b33e3aac4e3eac608ee2ea7421303d5')
build() {
cd ${pkgname}
# Generate protobuf files
python -m grpc_tools.protoc \
--proto_path=protos \
--python_out=klayout_pex_protobuf \
$(find protos -name '*.proto')
# Generate tech files
python scripts/gen_tech_pb klayout_pex_protobuf
# Build package
python -m build --wheel --no-isolation
}
check() {
cd "${pkgname}"
# TODO: slow tests require more extensive setup
pytest \
-v \
-m "not slow and not fastercap"
}
package() {
cd "${pkgname}"
python -m installer --destdir="$pkgdir" dist/*.whl
}
# vim: set sw=4 ts=4 et:
|