blob: a0c8346bc472de1095f02f47635d77fa2bb12167 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Andrew O'Neill <andrew at meanjollies dot com>
# Contributor: Gavin Lloyd <gavinhungry@gmail.com>
# Contributor: Carsten Feuls <archlinux@carstenfeuls.de>
pkgname=klog
pkgver=1.6
pkgrel=1
pkgdesc='A multiplatform free hamradio logger'
arch=('x86_64')
url='https://www.klog.xyz'
license=('GPL3')
makedepends=('qt5-tools' 'gendesk')
depends=('qt5-base' 'qt5-charts' 'qt5-serialport' 'hamlib')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ea4k/${pkgname}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('bdc75f53c0dbe5df4205b7035c721062792e1ab6ca35d75bb010f9db9bf3e1b5')
prepare() {
cd "${pkgname}-${pkgver}"
sed -i 's/ -Werror//g' tests/utilities/utilities.pro # shh look away
gendesk --pkgname "${pkgname}" --pkgdesc "${pkgdesc}" --exec "/usr/bin/${pkgname}" -n
}
build() {
cd "${pkgname}-${pkgver}"
qmake-qt5 PREFIX=/usr KLog.pro
make
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 src/build/target/klog "${pkgdir}/usr/bin/klog"
install -Dm644 src/klog.1 "${pkgdir}/usr/share/man/man1/klog.1"
install -Dm644 src/img/${pkgname}_512x512.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 ${pkgname}.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|