blob: 492f1b44d593f6a14ed3fd957123ddd6adedae27 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Anton Filimonov <anton.filimonov@gmail.com>
pkgname=klogg
pkgver=22.06
_subversion=0.1289
pkgrel=4
pkgdesc="A multi-platform GUI application that helps browse and search through long and complex log files. It is designed with programmers and system administrators in mind and can be seen as a graphical, interactive combination of grep, less, and tail"
arch=('x86_64')
url='https://klogg.filimonov.dev'
license=('GPL3')
provides=('klogg')
conflicts=('klogg')
depends=('qt5-base' 'hicolor-icon-theme' 'hyperscan' 'xxhash' 'uchardet' 'tbb')
makedepends=('cmake' 'git')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/variar/klogg/archive/refs/tags/v${pkgver}.tar.gz"
"https://github.com/variar/klogg/releases/download/v${pkgver}/${pkgname}-${pkgver}.${_subversion}.deps.tar.gz"
"crash_handler.patch"
"qt6_karchive.patch")
sha256sums=('a6a68b45d828a0de34572a77a25cb0bac7ce15f7e0328b4f4dae573b990e3970'
'c9316454cbca126ee7fb55dd7b3af5bab92a914ec4df950fcf7c435a2f2c8276'
'653ad64febd55ee1b62c4604ecf7ac43574f81ca55f7d672a339c02114661be6'
'606ec346a361dfe4e4cf9743df43c8897677553d9b2d028af157b2220e580bfc')
prepare() {
patch -p0 --input="${srcdir}/crash_handler.patch"
patch -p0 --input="${srcdir}/qt6_karchive.patch"
}
build() {
KLOGG_VERSION=${pkgver}.${_subversion} \
cmake \
-B "${pkgname}-${pkgver}/build" \
-S "${pkgname}-${pkgver}" \
-DCMAKE_BUILD_TYPE='RelWithDebugInfo' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCPM_USE_LOCAL_PACKAGES=ON \
-DCPM_SOURCE_CACHE=${srcdir}/cpm_cache \
-DWARNINGS_AS_ERRORS=OFF \
-DKLOGG_USE_SENTRY=OFF \
-DKLOGG_BUILD_TESTS=OFF
make -C "${pkgname}-${pkgver}/build" klogg
}
package() {
make -C "${pkgname}-${pkgver}/build" DESTDIR="$pkgdir" install
install -D -m644 "${pkgname}-${pkgver}/COPYING" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|