summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 01da364d38f4a6f94b549e9ef3b34ff3dd73cf6b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Daniel Micay <danielmicay@gmail.com>
_gitname=kmscon
pkgname=kmscon-git
pkgver=a
pkgrel=1
epoch=2
pkgdesc='Terminal emulator based on Kernel Mode Setting (KMS)'
arch=(i686 x86_64)
url='https://github.com/dvdhrm/kmscon'
license=('MIT')
depends=(systemd libdrm mesa libegl libgles pango libxkbcommon xkeyboard-config libtsm)
makedepends=(git libxslt docbook-xsl linux-api-headers)
options=(!libtool)
provides=(kmscon)
conflicts=(kmscon)
source=(git://people.freedesktop.org/~dvdhrm/kmscon)
md5sums=(SKIP)

pkgver() {
  cd $_gitname
  git describe | sed 's/^kmscon\-//; s/\([^-]*-g\)/r\1/; s/-/./g'
}

build() {
  cd $_gitname
  ./autogen.sh --prefix=/usr --disable-wlterm
  make
}

package() {
  cd $_gitname
  make DESTDIR="$pkgdir/" install
  mkdir -p "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/usr/lib/systemd/system"
  cp COPYING "$pkgdir/usr/share/licenses/$pkgname/"
  cp docs/kmscon{,vt@}.service "$pkgdir/usr/lib/systemd/system/"
}