blob: 10b1732969f9e523b24734fda4c670511e5942b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
###############################################################################
# INSTRUCTIONS #
# ------------ #
# #
# API changes between different Kodi versions make it necessary to specify #
# the version of Kodi you want to build this package for. You can choose #
# between Isengard (15), Jarvis (16), Krypton (17) and git master (99). Do so #
# in the following line. #
# #
###############################################################################
API=17
pkgname=kodi-platform-git
pkgver=r53.c8188d8
pkgrel=1
pkgdesc='Kodi platform support library'
arch=('armv7h' 'i686' 'x86_64')
url="https://github.com/xbmc/kodi-platform"
license=('GPL')
makedepends=('cmake' 'git')
depends=('kodi')
provides=('kodi-platform')
conflicts=('kodi-platform')
source=("${pkgname}::git+https://github.com/xbmc/kodi-platform.git")
md5sums=('SKIP')
# Corresponding commit IDs are taken from
# https://github.com/xbmc/xbmc/blob/$BRANCH/project/cmake/addons/depends/common/kodi-platform/kodi-platform.txt
case "$API" in
15) depends+=('libplatform-legacy')
source[0]="${pkgname}::git+https://github.com/xbmc/kodi-platform.git#commit=054a42f66" ;;
16) depends+=('libplatform-legacy')
source[0]="${pkgname}::git+https://github.com/xbmc/kodi-platform.git#commit=15edaf78d" ;;
17) depends+=('p8-platform')
makedepends+=('kodi-dev')
source[0]="${pkgname}::git+https://github.com/xbmc/kodi-platform.git#commit=c8188d826" ;;
99) depends+=('p8-platform')
makedepends+=('kodi-dev') ;;
*) error "Unknown API version. Follow instructions in PKGBUILD." && false
esac
pkgver() {
cd "$pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
mkdir -p "$pkgname/build"
cd "$pkgname/build"
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DCMAKE_INSTALL_LIBDIR_NOARCH=/usr/lib \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_PREFIX_PATH=/usr/lib/kodi \
..
make
}
package() {
cd "$pkgname/build"
make DESTDIR="$pkgdir" install
}
|