blob: c4b4da5a70c8fa1d0bdcec557f0a91f28db8f2ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Aaron Coach <aur@awc.id.au>
pkgname=koito
_pkgname=Koito
pkgver=0.3.2
pkgrel=1
pkgdesc='Modern, themeable scrobbler that you can use with any program that scrobbles to ListenBrainz'
arch=('x86_64')
url='https://koito.io/'
license=('MIT')
depends=('libvips' 'libheif' 'imagemagick' 'openslide' 'poppler-glib')
install=koito.install
backup=('etc/koito.env')
makedepends=('go' 'npm' 'yarn' 'nodejs>=16' 'corepack')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/gabehf/Koito/archive/refs/tags/v$pkgver.tar.gz"
"koito.service"
"koito.env"
)
sha256sums=('9f6eaf521f875629cf0cb5021a5665d242d63243100cd92b5320a1d710be9f11'
'f82dc31307d11b402dc1a3466aee6b5cb8a4560105e3595ef411e7f4e1fdea43'
'd9cc7b0adcf4ee0094388697ddd5645cc8c76252985fd71a03c1d4d7a904bcfd')
build() {
cd "$srcdir/$_pkgname-$pkgver"
# --- Corepack Sandbox Setup ---
mkdir -p "$srcdir/corepack-bin"
export COREPACK_HOME="$srcdir/.corepack"
corepack enable --install-directory "$srcdir/corepack-bin"
export PATH="$srcdir/corepack-bin:$PATH"
# ------------------------------
export VITE_KOITO_VERSION="$pkgver"
export BUILD_TARGET="docker"
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
sed -i "s/-ldflags='-s -w'/-ldflags='-linkmode=external -X main.Version=$pkgver'/g" Makefile
make build
}
package() {
cd "$srcdir/$_pkgname-$pkgver"
install -Dm755 koito "$pkgdir"/usr/bin/koito
install -d "$pkgdir/usr/share/koito"
cp -a assets client \
"$pkgdir/usr/share/koito/"
install -Dm0640 ../koito.env "$pkgdir"/etc/koito.env
install -Dm0644 ../koito.service "$pkgdir"/usr/lib/systemd/system/koito.service
}
|