summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ebc6ffe47c788215706d59c7518f434a66371f06 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer : Thor M. K. Høgås <thor alfakrøll roht dott no>
pkgname=koku-xinput-wine
pkgver=1.2.3
pkgrel=1
_srcname="${pkgname}-${pkgver}"
pkgdesc="Adds xinput support to Wine without modifying the source binaries of Wine."
arch=('i686' 'x86_64')
url="https://www.github.com/KoKuToru/koku-xinput-wine"
license=('BSD')
provides=("${pkgname}")
conflicts=("${pkgname}-git")

makedepends=('cmake' 'wine')
makedepends_x86_64=('gcc-multilib')
depends_x86_64=('lib32-sdl2')
depends_i686=('sdl2')

source=("${pkgname}::${url}/archive/v${pkgver}.tar.gz")
sha256sums=('9e38ee4db53e43543845843d8f1689a43b0100e6b326fbe716209fad3ce356b6')

build() {
	cd "${srcdir}/${_srcname}"
	cmake -DCMAKE_BUILD_TYPE=Release .
	make
} 

package() {
	cd "${srcdir}/${_srcname}"
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/BSD2"

	if [ "$CARCH" == "x86_64" ]; then
		install -Dm755 koku-xinput-wine.so koku-xinput-wine64.so -t "${pkgdir}/usr/lib32/"
	else
		warning "i686 is not supported, although it may work, in this package."
		install -Dm755 koku-xinput-wine.so -t "${pkgdir}/usr/lib/"
	fi
}