PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: katt <magunasu.b97@gmail.com>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=konsole-git
pkgver=19.12.3.r783.g110d705f
pkgrel=1
arch=(x86_64)
url=https://kde.org/applications/system/konsole
pkgdesc="KDE's terminal emulator"
license=(GPL LGPL FDL)
groups=(kde-applications kde-utilities)
depends=(knotifyconfig kpty kparts kinit knewstuff)
makedepends=(extra-cmake-modules kdoctools git)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
optdepends=('keditbookmarks: to manage bookmarks')
source=(git+https://invent.kde.org/utilities/konsole.git)
sha256sums=('SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
    F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87           # Christoph Feck <cfeck@kde.org>
    D81C0CB38EB725EF6691C385BB463350D6EF31EF)          # Heiko Becker <heiko.becker@kde.org>

pkgver() {
    git -C "${pkgname%-git}" describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cmake -B build -S "${pkgname%-git}" \
        -DBUILD_TESTING=OFF
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}