PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: temidaradev <temidaradev@proton.me>
#
# pkgver / pkgrel / sha256sums are rewritten by scripts/publish-aur.sh at
# release time (from the release branch). Edit the package body here, not those.
pkgname=kopuz-bin
pkgver=0.19.0
pkgrel=1
pkgdesc="A modern music player (pre-built binary)"
arch=('x86_64')
url="https://github.com/Kopuz-org/kopuz"
provides=('kopuz')
conflicts=('kopuz')
license=('EUPL-1.2')
depends=(
    'webkit2gtk-4.1'
    'gtk3'
    'libsoup3'
    'glib-networking'
    'alsa-lib'
    'openssl'
    'xdotool'
    'dbus'
    'opus'
    'libayatana-appindicator'
)

optdepends=(
    'ffmpeg: converting YouTube downloads to MP3, FLAC or WAV'
)

source=("$pkgname-$pkgver.tar.gz::https://github.com/Kopuz-org/kopuz/releases/download/v${pkgver}/kopuz_v${pkgver}_x86_64-linux.tar.gz")
sha256sums=('0c3ce1be7f14003086cf081c502d355543c7b664f3228552805206b5171a5c0b')

package() {
    cd "kopuz-linux-x86_64"

    install -Dm755 kopuz "$pkgdir/usr/bin/kopuz"

    install -Dm644 "moe.kopuz.kopuz.desktop" \
        "$pkgdir/usr/share/applications/moe.kopuz.kopuz.desktop"
    sed -i "s|Exec=kopuz|Exec=/usr/bin/kopuz|" \
        "$pkgdir/usr/share/applications/moe.kopuz.kopuz.desktop"

    install -Dm644 "logo.png" \
        "$pkgdir/usr/share/icons/hicolor/256x256/apps/moe.kopuz.kopuz.png"

    install -Dm644 "moe.kopuz.kopuz.metainfo.xml" \
        "$pkgdir/usr/share/metainfo/moe.kopuz.kopuz.metainfo.xml"

    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}