blob: a8162034b2ffcf216fa703e973e5b21020555cc9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_name="koyeb"
_pkgname="${_name}-cli"
pkgname="${_pkgname}-git"
pkgver=5.3.1.r2.g7a523f6
pkgrel=1
pkgdesc="Manage your Koyeb serverless infrastructure directly from your terminal"
arch=('x86_64' 'aarch64')
url="https://github.com/koyeb/${_pkgname}"
license=('Apache-2.0')
depends=('glibc')
makedepends=('git' 'go')
provides=("${_pkgname}=${pkgver%%.r*}")
conflicts=("${_pkgname}")
_pkgsrc="${_pkgname}"
source=("${_pkgsrc}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgsrc}"
git describe --long --tags --abbrev=7 | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build" "completions"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${_name}" ./"cmd/${_name}"
for _sh in bash fish zsh powershell; do
./"build/${_name}" completion "${_sh}" > "completions/${_name}.${_sh}"
done
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${_name}" "${pkgdir}/usr/bin/${_name}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
cd "completions"
install -vDm644 "${_name}.bash" "${pkgdir}/usr/share/bash-completion/completions/${_name}"
install -vDm644 "${_name}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_name}.fish"
install -vDm644 "${_name}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_name}"
install -vDm644 "${_name}.powershell" "${pkgdir}/usr/share/powershell/Completions/${_name}.ps1"
}
|