PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=kproperty-git
pkgver=2.96.0.r467.3cac19f
pkgrel=1
pkgdesc="A property editing framework with editor widget similar to what is known from Qt Designer. (GIT version)"
url='https://www.kde.org/applications/graphics/kproperty'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('kguiaddons' 'kwidgetsaddons')
makedepends=('extra-cmake-modules' 'kdoctools' 'git' 'python')
conflicts=('kproperty')
provides=('kproperty')
source=('git://anongit.kde.org/kproperty.git')
sha1sums=('SKIP')


pkgver() {
  cd kproperty
  _ver="$(cat CMakeLists.txt | grep KPROPERTY_VERSION | cut -d '"' -f2)"
  echo -e "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build

  cmake ../kproperty \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}