blob: 4fb959dea394a3adf928a9cfc690a30f5f23cd57 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgbase="kratos"
pkgname=(
"${pkgbase}"
"protoc-gen-go-errors"
"protoc-gen-go-http"
)
pkgver=2.9.2
pkgrel=1
pkgdesc="Your ultimate Go microservices framework for the cloud-native era"
arch=(
'x86_64'
)
url="https://go-kratos.dev"
_url="https://github.com/go-kratos/${pkgbase}"
license=(
'MIT'
)
makedepends=(
'go'
)
checkdepends=(
'git'
)
_pkgsrc="${_url##*/}-${pkgver}"
source=(
"${_pkgsrc}.tar.gz::${_url}/archive/refs/tags/v${pkgver}.tar.gz"
)
sha256sums=('a87a03735688a79b56b106c77e7c301f1b5bf0edbf961b2732d2daac86015a40')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
for _name in "${pkgname[@]}"; do
pushd "cmd/${_name}" >/dev/null
go mod download -modcacherw -x
go mod verify
popd >/dev/null
done
mkdir -p "build" "completions"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
for _name in "${pkgname[@]}"; do
pushd "cmd/${_name}" >/dev/null
go build -v -o "${srcdir}/${_pkgsrc}/build/${_name}" .
popd >/dev/null
done
for _sh in bash fish zsh powershell; do
./"build/${pkgbase}" completion "${_sh}" > "completions/${pkgbase}.${_sh}"
done
}
check() {
cd "${srcdir}/${_pkgsrc}"
for _name in "${pkgname[@]}"; do
pushd "cmd/${_name}" >/dev/null
go test ./...
popd >/dev/null
done
}
package_kratos() {
depends+=(
'glibc'
'go'
'protobuf'
'protoc-gen-go'
'protoc-gen-go-grpc'
"protoc-gen-go-errors>=${pkgver}"
"protoc-gen-go-http>=${pkgver}"
"protoc-gen-validate"
)
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
}
package_protoc-gen-go-errors() {
pkgdesc="Protobuf plugin that generates error codes and RPC error helpers"
url="${_url}/tree/main/cmd/${pkgname}"
depends=(
'glibc'
'protobuf'
'protoc-gen-go'
)
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_protoc-gen-go-http() {
pkgdesc="Protobuf plugin that generates RPC service templates for HTTP APIs"
url="${_url}/tree/main/cmd/${pkgname}"
depends=(
'glibc'
'protobuf'
'protoc-gen-go'
)
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|