PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Antonio Rojas <arojas@archlinux.org>

pkgname=kreport
pkgver=3.2.0
pkgrel=7
pkgdesc='A framework for creation and generation of reports in multiple formats'
arch=(x86_64)
url='https://apps.kde.org/es/kexi-3.3/'
license=(GPL-2.0-only)
depends=(gcc-libs
         glibc
         kconfig5
         kcoreaddons5
         kwidgetsaddons5
         kproperty
         qt5-base
         qt5-declarative
         qt5-tools)
makedepends=(extra-cmake-modules
             python)
source=(https://download.kde.org/stable/$pkgname/src/$pkgname-$pkgver.tar.xz{,.sig}
        https://invent.kde.org/libraries/kreport/-/commit/5d3053ea.patch)
sha256sums=('22716d719654e8f887fe4d33654e252ddf3d3d818c44e15a8af0e6f2e7d6ccd7'
            'SKIP'
            'c4f0b7ead3b0ffb1bd1d1997a78a48496c1de5dea11d48c2b9491cbabf4c5543')
validpgpkeys=(4866BAF713B465677A4059643C7C0E201B6524DB) # Jarosław Staniek <staniek@kde.org>

prepare() {
  patch -d $pkgname-$pkgver -p1 < 5d3053ea.patch # Fix missing symbols with GCC 10
  sed -e '/SetKReportCMakePolicies/d' -i $pkgname-$pkgver/CMakeLists.txt # Fix build with cmake 4
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_TESTING=OFF \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}