summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 14fcd280a0482d6c191bb2387b760013ac351aa0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Victor <victor@xirion.net>

pkgname=krew
pkgver=0.4.4
pkgrel=2
pkgdesc="Find and install kubectl plugins"
arch=(
  x86_64
  aarch64
  armv7h
)
url="https://github.com/kubernetes-sigs/krew"
license=(Apache-2.0)
depends=(
  git
  glibc
  kubectl
)
makedepends=(go)
install=kubectl-krew.install

source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('dd11ef2d56a0897d38ac219f17332effbd09a3c6a1f68974635b925ba129cd35')

_archive="$pkgname-$pkgver"

build() {
  cd "$_archive"

  export CGO_LDFLAGS="$LDFLAGS"
  export CGO_CFLAGS="$CFLAGS"
  export CGO_CPPFLAGS="$CPPFLAGS"
  export CGO_CXXFLAGS="$CXXFLAGS"
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"

  _ld_flags="-linkmode external"
  _ld_flags="$_ld_flags -X sigs.k8s.io/krew/internal/version.gitTag=v$pkgver"
  go build -buildvcs=false -ldflags "$_ld_flags" -o . ./cmd/...
}

check() {
  cd "$_archive"

  unset KREW_ROOT
  KREW_BINARY="$PWD/krew" go test ./...
}

package() {
  cd "$_archive"

  install -Dm755 krew "$pkgdir/usr/bin/kubectl-krew"
  install -Dm755 validate-krew-manifest "$pkgdir/usr/bin/validate-krew-manifest"

  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  cp --archive -t "$pkgdir/usr/share/doc/$pkgname" docs/*
}