blob: 7a8e8422cb1aafb6b605255b38e19cda43392866 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: David Birks <david@tellus.space>
# Contributor: Victor Demonchy <demonchy.v@gmail.com>
# Contributor: Wael Nasreddine <wael.nasreddine@gmail.com>
pkgname=kubetail
pkgver=1.6.18
pkgrel=1
pkgdesc='Tail Kubernetes logs from multiple pods'
arch=(any)
url='https://github.com/johanhaleby/kubetail'
license=(Apache)
depends=(
bash
kubectl
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('62ba29b3a869bba5b2ddf8c0fbbd307330dfe8cf8f3d47ae459c327b66afbb93')
_archive="$pkgname-$pkgver"
package() {
cd "$_archive"
install -Dm 755 kubetail "$pkgdir/usr/bin/kubetail"
# Populate shell completions
install -Dm 644 completion/kubetail.bash "$pkgdir/usr/share/bash-completion/completions/kubetail"
install -Dm 644 completion/kubetail.zsh "$pkgdir/usr/share/zsh/site-functions/_kubetail"
install -Dm 644 completion/kubetail.fish "$pkgdir/usr/share/fish/vendor_completions.d/kubetail.fish"
}
|