blob: 0581ccecbd9360a3e30f350bbd322d60f316d29a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer : Daniel Bermond < yahoo-com: danielbermond >
# Contributor: Devaux Fabien <fdev31@gmail.com>
pkgname=kvazaar-git
pkgver=1.2.0.r71.g6be81959
pkgrel=1
pkgdesc='An open-source HEVC encoder (git version)'
arch=('i686' 'x86_64')
url='http://ultravideo.cs.tut.fi/#encoder'
license=('LGPL')
depends=('glibc' 'gcc-libs' 'crypto++')
makedepends=('git' 'yasm')
provides=('kvazaar' 'libkvazaar.so')
conflicts=('kvazaar')
source=("$pkgname"::'git+https://github.com/ultravideo/kvazaar.git'
'kvazaar-submodule-greatest'::'git+https://github.com/ultravideo/greatest.git')
sha256sums=('SKIP'
'SKIP')
prepare() {
cd "$pkgname"
git submodule init
git config --local submodule.greatest.url "${srcdir}/kvazaar-submodule-greatest"
git submodule update
}
pkgver() {
cd "$pkgname"
# git, tags available
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
cd "$pkgname"
./autogen.sh
./configure \
--prefix='/usr' \
--enable-largefile \
--enable-static='no' \
--enable-shared='yes' \
--enable-fast-install='yes' \
--with-cryptopp
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
}
|