PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Vasiliy Stelmachenok <cabopust@yandex.ru>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kwin-unredirect
pkgver=5.21.3
pkgrel=2
pkgdesc='KWin compositor with unredirect patch from Sporif'
arch=(x86_64)
url='https://kde.org/plasma-desktop/'
license=(LGPL)
depends=(kscreenlocker xcb-util-cursor plasma-framework kcmutils kwayland-server breeze
         qt5-script pipewire libqaccessibilityclient lcms2)
makedepends=(extra-cmake-modules qt5-tools kdoctools krunner)
conflicts=(kwin)
provides=(kwin)
optdepends=('qt5-virtualkeyboard: virtual keyboard support for kwin-wayland')
groups=(plasma)
source=("https://download.kde.org/stable/plasma/$pkgver/kwin-$pkgver.tar.xz"
        'unredirect.patch')
install=$pkgname.install
sha256sums=('7c38049930f63875719c4405991c13ab436d2a2d2ad401b006e94250dd8d205a'
            'aec3616247dccfc488f01c63af1e3d9bc846b1e22cb29b8698311e3efc74ce48')

prepare() {
    cd "${srcdir}/kwin-$pkgver"
    # https://gist.github.com/Sporif/7f18d95dd89af8ec386dd1fbbe11bf67
    patch -Np1 -i "${srcdir}/unredirect.patch"
}

build() {
  cmake -B build -S kwin-$pkgver \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}