blob: 0be50f75dd6e304774ee0bbfc81b96b969cee1ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: WoefulDerelict <WoefulDerelict at GMail dot com>
# Contributor: speps <speps at aur dot archlinux dot org>
pkgname=ladish-git
pkgver=0.3.r147.g5fe205f
pkgrel=3
pkgdesc="Session management system for JACK."
arch=('any')
url="https://launchpad.net/ladish"
license=('GPL2')
depends=('jack2-dbus' 'dbus-glib' 'laditools-git' 'flowcanvas<=0.7.1' 'a2jmidid')
makedepends=('git' 'python2')
provides=("ladish" "lash")
conflicts=("ladish" "lash")
install=${pkgname}.install
source=("git://repo.or.cz/ladish.git")
md5sums=('SKIP')
pkgver() {
cd ${srcdir}/ladish
( set -o pipefail
git describe --long --tags 2>/dev/null | sed 's/^ladish-//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "${srcdir}/ladish"
git checkout master
}
build() {
cd "${srcdir}/ladish"
export PYTHON=/usr/bin/python2
sed -i "s|env python|&2|" ladish_control
sed -i "s|\(RELEASE = \).*|\1True|" wscript
python2 waf configure --prefix=/usr \
--enable-liblash \
--enable-pylash
python2 waf
}
package() {
cd "${srcdir}/ladish"
python2 waf install --destdir="${pkgdir}/"
}
|