PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=lagrange-git
pkgver=1.17.5.r3.gd519fad4
pkgrel=1
pkgdesc="A desktop GUI client for browsing Geminispace"
arch=('i686' 'x86_64')
url="https://gmi.skyjake.fi/lagrange/"
license=('BSD')
depends=('glibc' 'fribidi' 'harfbuzz' 'hicolor-icon-theme' 'libunistring' 'libwebp' 'mpg123' 'openssl' 'pcre' 'sdl2' 'zlib')
makedepends=('git' 'cmake' 'zip')
optdepends=('mpg123')
provides=("lagrange=$pkgver")
conflicts=('lagrange')
source=("git+https://github.com/skyjake/lagrange.git")
sha256sums=('SKIP')


prepare() {
  cd "lagrange"

  git submodule update --init --recursive
}

pkgver() {
  cd "lagrange"

  _tag=$(git tag -l --sort -v:refname | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//;s/-/./g'
}

build() {
  cd "lagrange"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    ./
  make -C "_build"
}

package() {
  cd "lagrange"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/lagrange"
}