blob: 9c5f2886ee69cafec841b8f7ed309e08da944af1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Benjamin Denhartog <ben@sudoforge.com>
_pkgname=LanguageClient-neovim
pkgname=languageclient-neovim-bin
pkgver=0.1.158
pkgrel=1
pkgdesc="Language Server Protocol (LSP) support for Vim and NeoVim."
url="https://github.com/autozimu/LanguageClient-neovim"
provides=('languageclient-neovim')
license=('MIT')
arch=('x86_64')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz"
"${url}/releases/download/${pkgver}/${pkgname%-neovim-bin}-${pkgver}-x86_64-unknown-linux-musl")
sha256sums=('d563d1cf88b5dac8857903d7f559547839981226b16f72dd6e6ecef54b733edf'
'c11def5ef5c180a2b8406dca014e24d0d67289a4830c5076cb8e62cec6c21558')
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
# Install the license file
install -D -m 644 \
"LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname%-bin}/LICENSE.txt"
# Install the executable to local bin/ directory to take advantage of
# the iterative copying, below. `install` is used to ensure the correct
# mode is set.
install -D -m 755 \
"${srcdir}/${pkgname%-neovim-bin}-${pkgver}-x86_64-unknown-linux-musl" \
"bin/${pkgname%-neovim-bin}"
# Create runtime directories
install -d -m 755 "${pkgdir}/usr/share/vim/vimfiles"
install -d -m 755 "${pkgdir}/usr/share/nvim/runtime"
# Install vimfiles from the project into the appropriate runtime directories
for d in autoload bin doc plugin rplugin; do
case $d in
rplugin)
# vim doesn't have "remote plugins", so we only need to move this into
# neovim's runtime directory
cp -r "$d" "${pkgdir}/usr/share/nvim/runtime"
;;
*)
cp -r "$d" "${pkgdir}/usr/share/vim/vimfiles"
cp -r "$d" "${pkgdir}/usr/share/nvim/runtime"
esac
done
}
|