PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Jorge Pizarro-Callejas (jorgicio) <jpizarrocallejas@gmail.com>
# Former Maintainer: sigmacool
# Contributor: FabioLolix

pkgname=lanshare-git
_pkgname="LAN-Share"
pkgver=1.2.1.r28.gaa7a3bc
pkgrel=1
pkgdesc="LAN Share is a cross platform local area network file transfer application, built using Qt GUI framework."
arch=(i686 x86_64 arm armv6h armv7h aarch64)
url="https://github.com/abdularis/LAN-Share"
license=(GPL3)
depends=(qt5-base)
makedepends=(git)
source=("git+https://github.com/abdularis/$_pkgname.git")
sha256sums=('SKIP')
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})

pkgver() {
	cd "${srcdir}/${_pkgname}"
	git describe --long --tags --exclude continuous | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$_pkgname/packaging/linux/debian"
  sed -i "/Path=.*/d" LANShare.desktop 
  sed -i "s^Exec=.*^Exec=/usr/bin/LANShare^" LANShare.desktop 
  sed -i "s/Name\[en_US\]=.*/Name\[en_US\]=LANShare/" LANShare.desktop
}

build() {
  cd "$srcdir/$_pkgname/src"
  qmake
  make
}

package() {
  install -Dm755 "$srcdir/$_pkgname"/src/LANShare "$pkgdir"/usr/bin/LANShare
  ln -s /usr/bin/LANShare "$pkgdir/usr/bin/lanshare"

  cd "$srcdir/$_pkgname/packaging/linux/debian"
  install -D LANShare.desktop  "$pkgdir"/usr/share/applications/LANShare.desktop
  install -D lanshare-icon.png "$pkgdir"/usr/share/pixmaps/lanshare-icon.png
}