PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Eli Schwartz <eschwartz93@gmail.com>
# Contributor: Thiago Perrotta <echo dGhpYWdvcGVycm90dGE5NUBnbWFpbC5jb20K | base64 -d >

# All my PKGBUILDs are managed at https://github.com/eli-schwartz/pkgbuilds

pkgname=lastpass-cli-git
pkgver=0.9.0.r4.gb5e4f4e
pkgrel=1
pkgdesc="LastPass command line interface tool (git version)"
arch=('i686' 'x86_64')
url="https://lastpass.com/"
license=('GPL2')
depends=('openssl' 'curl' 'libxml2')
makedepends=('asciidoc' 'git')
optdepends=('xclip: clipboard support'
            'pinentry: securely read passwords')
source=("git://github.com/lastpass/${pkgname%-git}.git")
md5sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname%-git}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${pkgname%-git}"
    make all doc
}

package() {
    cd "${srcdir}/${pkgname%-git}"
    make DESTDIR="${pkgdir}/" install install-doc
}